{{tag>dokuwiki usb apache autoit}}
<WRAP hide>
== Menu DokuWikiStick ==
</WRAP>

Ce script [[https://www.autoitscript.com/site/autoit/|AutoIt]] permet de rendre plus esthétique le lancement de DokuWikiStick (pas de batch ou de MicroApache qui reste planté au milieu de l'écran) et d'ajouter dans la barre de tâches Windows une icône permettant d'accéder à quelques raccourcis pratiques :


<WRAP left 45%>
  * ouvrir le wiki dans le navigateur internet par défaut
  * relancer MicroApache
  * ouvrir le dossier ''DokuWikiStick'' dans l'explorateur Windows
  * si un dossier ''GitHub'' existe dans les documents, les options ouvrir le site ''github.com'' et explorer le dossier s'ajoutent au menu
  * fermeture de MicroApache (et du script).
</WRAP>
<WRAP right 45%>
{{ info:logiciels:doku:dokuwikistick-systray.png?300 |}}</WRAP>
<WRAP clear></WRAP>


Voici la source :
<file bash DokuWikiStick.au3>#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=DokuWikiStickGeekitude.ico
#AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <Constants.au3>
#include <WindowsConstants.au3>

Opt("TrayAutoPause", 0)
Opt("TrayMenuMode", 3)

TraySetToolTip ("DokuWikiStick")

If FileExists(@ScriptDir & "\server\mapache.exe") Then
	TrayTip("DokuWikiStick", "Starting MicroApache...", 2, 2)
  	FileChangeDir (@ScriptDir & "\server")
	Run("mapache.exe", "", @SW_MINIMIZE)
	ShellExecute("http://localhost:8800/doku.php")
	Menu()
Else
	MsgBox(16, "Error", "Missing \server\mapache.exe")
	Exit
EndIf

Func Menu()
	Local $idBrowseDWS = TrayCreateItem("Browse DokuWikiStick website")
	Local $idRestart = TrayCreateItem("Restart MicroApache")
	Local $idExploreDWS = TrayCreateItem("Explore DokuWikiStick folder")
	If FileExists(@MyDocumentsDir & "\GitHub") Then
		TrayCreateItem("")
		Local $idBrowseGH = TrayCreateItem("Browse GitHub website")
		Local $idExploreGH = TrayCreateItem("Explore Documents\GitHub folder")
	EndIf
	TrayCreateItem("")
	Local $idExit = TrayCreateItem("Exit")
	While 1
		Switch TrayGetMsg()
			Case $idBrowseDWS
				ShellExecute("http://localhost:8800/doku.php")
			Case $idRestart
				TrayTip("DokuWikiStick", "Restarting MicroApache...", 2, 2)
				Run("ApacheKill.exe")
				Sleep(1000)
				Run("mapache.exe")
			Case $idExploreDWS
				ShellExecute(@ScriptDir)
			Case $idBrowseGH
				ShellExecute("https://github.com")
			Case $idExploreGH
				ShellExecute(@MyDocumentsDir & "\GitHub")
			Case $idExit
				KillApache()
		EndSwitch
	WEnd
EndFunc

Func KillApache()
	TrayTip("DokuWikiStick", "Killing MicroApache...", 2, 2)
	Run("ApacheKill.exe")
	Sleep(1000)
	Exit
EndFunc</file>

Ce fichier ''DokuWikiStick.au3'' doit être compilé en procédant de la manière suivante :

  * Rendez-vous à la rubrique [[https://www.autoitscript.com/site/autoit/downloads/|téléchargements]] du site d'AutoIt
  * Téléchargez et installez ''AutoIt Full Installation'' (choisissez l'option d'éditer les script à l'ouverture)
  * Téléchargez et installez ''AutoIt Script Editor'' (vous pourrez compiler le script sans lui mais pas choisir son icône)
  * Téléchargez le fichier source ''DokuWikiStick.au3'' ci-dessus et l'une de ces icônes : [[http://www.geekitude.fr/externe/dokuwiki/dokuwikistick/DokuWikiStick.ico|{{info:logiciels:doku:dokuwikistick.ico?40}}]] (créée directement à partir d'une image du [[http://www.splitbrain.org/blog/2007-12/01-dokuwiki_on_a_stick|blog d'Andreas Gohr]] ou [[http://www.geekitude.fr/externe/dokuwiki/dokuwikistick/DokuWikiStickGeekitude.ico|{{info:logiciels:doku:dokuwikistickgeekitude.ico?40}}]] (créée par mes soins à partir de [[https://openclipart.org/detail/167170/usb-thumb-drive-3-by-rygle|ce clipart]])
  * Ouvrez la source du script dans //AutoIt Script Editor//
  * Dans le menu [Tools], sélectionnez [Compile]
  * Sélectionnez l'icône que vous avez choisie (si l'icône n’est pas visible c'est que le chemin est erroné)
  * Cliquez enfin sur le bouton [Compile Script]

Vous pouvez aussi télécharger directement l'exécutable [[http://www.geekitude.fr/externe/dokuwiki/dokuwikistick/DokuWikiStick.exe|ici même]].